AC_INIT([exp005], [0.1], [don@drexel.edu])
AM_INIT_AUTOMAKE([-Wall, -Werror, -Wno-portability])
AC_PROG_CC
AM_CONFIG_HEADER([config.h])
AC_CONFIG_FILES([
	Makefile
	src/Makefile
])

##################
# MODULE: OpenGL #
##################

# Note that this project will not build on systems where the OpenGL
# support libraries do not include support for buffer objects.

# Check for OpenGL libraries GLUT, GLU and GL.  OpenGL is used for the
# visualization rendering and interaction.
AX_CHECK_GLUT

###############
# MODULE: DB2 #
###############

# Check for DB2 client library.
AC_SEARCH_LIBS([sqlastrt],[db2],[],
[AC_MSG_ERROR(The DB2 client libraries are needed to build the system. After installation of the client it may be necessary to add -L/home/db2inst1/sqllib/lib to LDFLAGS.)])

# Check for DB2 client headers.
AC_CHECK_HEADERS([sqladef.h],[],
[AC_MSG_ERROR(The DB2 client headers are needed to build the system. After installation of the client it may be necessary to add -I/home/db2inst1/sqllib/include to CPPFLAGS.)])

##########################
# MODULE: BROWSER PLUGIN #
##########################

# Libtool is used to build the library for the browser plugin.
AC_PROG_LIBTOOL

# Check for the Gecko Plugin API
AC_CHECK_HEADERS([npapi.h],[],
[AC_MSG_ERROR(The Gecko Plugin API (NPAPI) is needed to build the system. Information on this API can be found on-line at https://developer.mozilla.org/en/Plugins. Debian users can add the package xulrunner-dev and add -I/usr/include/xulrunner-1.9/unstable to CPPFLAGS.)])

AC_OUTPUT